;
; TITLE 'B&O Datalink to Serial convertor'	
;
; Copyright (c) 2006 Ivor Hewitt
; Licensed under the GNU GPL Version 2 or later
;
	LIST	P=16F84
	__CONFIG _WDT_OFF & _CP_OFF & _HS_OSC & _PWRTE_ON
	ERRORLEVEL -302	

;; beolink message processor
;;
;; listens for bang and olufsen beolink messages and relays them on as
;; serial hex strings in the format:  "00 0000 00 00 00 \r\n"
;; representing 4 bits header, a series of 5 bits address and as many 8 bits message characters as necessary
;;
;; Serial protocol: 115200,N,8,1
;;
;; Notes:
;;	1. Currently only tested with messages from a BEO4 or Ouverture
;;	2. 2-way comms to be implemented.
;;
;; Ivor Hewitt (ivor at ivor.org)
;; http://www.ivor.it
;;
	
include "p16f84.inc"

	#define TXline		1
	#define	TXport		PORTB,TXline
	#define TXbit		(1<<TXline)
	#define TXmask		0xff-(1<<TXline)
	
	#define ST_START	MSG_STATUS, 0
	#define ST_HDR		MSG_STATUS, 1
	#define ST_ADR1		MSG_STATUS, 2
	#define ST_MSG		MSG_STATUS, 3
	
  org    0x0c
W_TEMP		res 1
STATUS_TEMP	res 1
OPTION_TEMP	res 1

TEMP1		res 1
TEMP2		res 1
TX_TMP		res 1
TMR_TMP		res 1

MSG		res 1
MSG_BITS	res 1
MSG_BYTES	res 1
MSG_STATUS	res 1

MSG_FMT		res 1
MSG_ADR1	res 1
MSG_DAT		res 1

ADDR_NUM	res 1
	
  org	0x000
	goto	main
	
  org	0x004
 	goto	isr
  
MESSAGE
	dt	"Ready\r\n",0
  
isr:
	bcf	INTCON, GIE
	btfsc	INTCON, GIE
	goto	isr
	
	movwf	W_TEMP
	swapf	W_TEMP,F
	banksel	OPTION_REG
	swapf	OPTION_REG,W
	movwf	OPTION_TEMP
	banksel	STATUS
	swapf	STATUS,W
	movwf	STATUS_TEMP
	
	btfsc	INTCON, INTF
	goto	isr_rb0		; rb0 interrupt
	btfsc   INTCON, T0IF
	goto    isr_tmr0	; timer overflow
int_ret:
	swapf	STATUS_TEMP,W
	movwf	STATUS
	banksel	OPTION_REG
	swapf	OPTION_TEMP,W
	movwf	OPTION_REG
	banksel	STATUS
	swapf	W_TEMP,W
	retfie

isr_tmr0:			; took too long, wipe buffers?
        bcf     INTCON,T0IF
	goto	clean

isr_rb0:			; datalink signal
	movfw	TMR0
	movwf	TMR_TMP		; get the high timer
	
	movlw	0x3
	movwf	TMR0

	swapf	TMR_TMP,f
	btfsc	TMR_TMP,3
	goto	bitclean		; overflow
	movlw	0x07
	andwf	TMR_TMP,w
	
	addwf	PCL,f
	goto	bitclean
	goto	t1
	goto	bitclean
	goto	t2
	goto	t3
	goto	bitclean
	goto	t4
	goto	t5
		
t1:
	rlf	MSG,f
	btfss	MSG,1		; was previous bit0 - error
	goto	bitclean	; reset
	bcf	MSG, 0		; another bit
	goto	bitproc
t2:
	rlf	MSG,f
	
	btfss	MSG,1
	bcf	MSG,0
	btfsc	MSG,1
	bsf	MSG,0
	goto	bitproc
t3:
	rlf	MSG,f
	btfsc	MSG,1		; was previous bit1 - error
	goto	bitclean	; reset
	bsf	MSG, 0		; another bit
	goto	bitproc
	
t5:				;start bit
        bsf     ST_START
	btfss	ST_MSG
	goto	rbint_ret
	
t4:				;stop bit
	btfss	ST_MSG		; no message? wipeout.
	goto	bitclean
	
	movlw	'\r'
	call	sendw
	movlw	'\n'
	call	sendw
	goto	bitclean
	
rbint_ret:
	bcf	INTCON, INTF
	goto	int_ret

bitproc:
	btfss	ST_START	; got a bit before a start token
	goto	bitclean	; reset
	
	incf	MSG_BITS,f

	btfss	ST_HDR		; have we got all the header?
	goto	bitprochdr
	
	btfss	ST_ADR1		; have we got all the addresses?
	goto	bitprocadr
	
	btfss	MSG_BITS, 3	; have we got a byte?
	goto	bitprocret
	
	clrf	MSG_BITS
	incf	MSG_BYTES,f

	movf	MSG, w
	movwf	MSG_DAT
	
;;spit it out	
	call	send_hex
 	
	bsf	ST_MSG

bitprocret:
	goto	rbint_ret

bitprochdr:			; we're looking for the header
	movlw	0x04		; did we get 4 bits yet?
	subwf	MSG_BITS, w
	bnz	bitprocret
	clrf	MSG_BITS
	movf	MSG, w
	movwf	MSG_FMT
	movlw	0x0F
	andwf	MSG_FMT,w
	movwf	MSG_FMT
	bsf	ST_HDR		; flag that we got the header	
	movwf	ADDR_NUM	; we need this many addrs

;;spit it out
	call	send_hex
	movlw	' '
	call sendw
 
	incf	ADDR_NUM, f	
	goto	bitprocret

bitprocadr:			; we're looking for an address
	movlw	0x05		; did we get 5 bits yet?
	subwf	MSG_BITS, w
	bnz	bitprocret
	
	clrf	MSG_BITS
	movf	MSG, w
	movwf	MSG_ADR1
	movlw	0x1F
	andwf	MSG_ADR1,f
	movfw	MSG_ADR1

;;spit it out	
	call	send_hex
	
	decfsz	ADDR_NUM,f	; got them all?
	goto	bitprocret
 
	movlw	' '
	call sendw
	
	bsf	ST_ADR1
	goto	bitprocret

bitclean:
	bcf	INTCON, INTF
clean:				; reset everything
	movlw	0x01
	movwf	MSG
	clrf	MSG_BITS
	clrf	MSG_STATUS
	clrf	MSG_BYTES
	clrf	MSG_FMT
	clrf	MSG_ADR1
	clrf	MSG_DAT
	goto	int_ret

init:
	banksel	TRISB
	movlw	b'00000001'
	movwf	TRISB
	movlw	b'00011111'	;tba. :)
	movwf	TRISA

	banksel	OPTION_REG
	movlw	b'00000110'
	movwf	OPTION_REG

	banksel	PORTB
	clrf	PORTB
	movlw	0x3
	movwf	TMR0

	movlw	0x01
	movwf	MSG
	clrf	MSG_BITS
	clrf	MSG_STATUS
	clrf	MSG_BYTES
	clrf	MSG_FMT
	clrf	MSG_ADR1
	clrf	MSG_DAT

        movlw   b'10110000'
        movwf   INTCON
	
	bsf	TXport
	return

main:
	call	init
	
	movlw	0xff
	call	slow
	
	movlw	MESSAGE		; confirm the link is up
	call	send_str
	
wait:
	goto	wait

send_str:
	movwf	TEMP2
	call	next_char
	iorlw	0
	skpnz
	return
	call	sendw
	incf	TEMP2,w
	goto	send_str
	
next_char:
	movwf	PCL

send_hex:
	movwf	TEMP2
	swapf	TEMP2,w
	andlw	0x0f
	
	call	xchar
	call	sendw
	
	movfw	TEMP2
	andlw	0x0f
	
	call	xchar
	call	sendw

	return	

;Hex char lookup table
xchar:
	addwf	PCL,f
	DT	"0123456789ABCDEF"

sendw:	; Send 115200,N,8,1
	bcf	TXport		; start bit	
	movwf	TX_TMP
	movlw	0x08
	movwf	TEMP1
	movfw	PORTB
	
bitloop:			; 8 data bits
	btfsc	TX_TMP, 0x00
	iorlw	TXbit
	btfss	TX_TMP, 0x00
	andlw	TXmask
;
	movwf	PORTB
	rrf	TX_TMP, f
	decfsz	TEMP1, f
	goto	bitloop
	nop
	nop
	nop
	nop
	nop
	bsf	TXport		; stop bit
	movlw	2
slow
	movwf	TEMP1
	decfsz	TEMP1,f		; slow tiger
	goto	$-1
	return

	end

; vim: ts=8 sw=8 noet